Contract Source Code:

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.6.0;

import "../GSN/Context.sol";
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () internal {
        address msgSender = _msgSender();
        _owner = msgSender;
        emit OwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(_owner == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        emit OwnershipTransferred(_owner, address(0));
        _owner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit OwnershipTransferred(_owner, newOwner);
        _owner = newOwner;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >=0.6.2 <0.7.0;

import "@openzeppelin/contracts/access/Ownable.sol";
import "./interfaces/ICurveDeposit.sol";

contract CurveRegistry is Ownable {
  struct Depositor {
    address contractAddress;
    uint8 numTokens;
    mapping(address => int128) coinToIndex;
  }

  mapping(address => Depositor) private lpTokenToDepositor;
  bool public locked;

  event AdapterRegistered(address adapter, bool isExit);

  constructor() public {
    // Needs to be explicitly set since we deploy through a Create2 proxy
    transferOwnership(tx.origin);
  }

  function addDepositor(ICurveDeposit depositor, address lpToken) external onlyOwner {
    require(lpTokenToDepositor[lpToken].contractAddress == address(0));
    lpTokenToDepositor[lpToken].contractAddress = address(depositor);

    bool usesUnderlying = depositorUsesUnderlying(depositor);

    for(int128 i = 0; true; i += 1) {
      address coin = getDepositorCoin(depositor, i, usesUnderlying);
      if (coin == address(0)) {
        lpTokenToDepositor[lpToken].numTokens = uint8(i);
        break;
      }

      lpTokenToDepositor[lpToken].coinToIndex[coin] = i + 1;
    }
  }

  function getDepositorAddress(address lpToken) external view returns (address) {
    return lpTokenToDepositor[lpToken].contractAddress;
  }

  function getDepositor(address lpToken, address coin) external view returns (address, uint8, int128) {
    Depositor storage depositor = lpTokenToDepositor[lpToken];

    int128 index = depositor.coinToIndex[coin];
    if (index == 0) {
      revert('UNSUPPORTED');
    }

    return (depositor.contractAddress, depositor.numTokens, index - 1);
  }

  function depositorUsesUnderlying(ICurveDeposit depositor) private view returns (bool) {
    try depositor.underlying_coins(0) {
      return true;
    } catch {
      return false;
    }
  }

  function getDepositorCoin(ICurveDeposit depositor, int128 index, bool usesUnderlying) private view returns (address) {
    if (usesUnderlying) {
      try depositor.underlying_coins(index) returns (address coin) {
        return coin;
      } catch {
        return address(0);
      }
    } else {
      try depositor.coins(index) returns (address coin) {
        return coin;
      } catch {
        return address(0);
      }
    }
  }

  function setLocked(bool _locked) external onlyOwner {
    locked = _locked;
  }

  function registerAdapter(bool isExit) external {
    require(!locked);
    emit AdapterRegistered(msg.sender, isExit);
  }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.6.2;

interface ICurveDeposit {
  // function get_virtual_price() external view returns (uint);

  function token() external returns (address);

  function coins(int128 i) external view returns (address);

  function underlying_coins(int128 i) external view returns (address);

  function add_liquidity(
    uint256[2] calldata amounts,
    uint256 min_mint_amount
  ) external;

  function add_liquidity(
    uint256[3] calldata amounts,
    uint256 min_mint_amount
  ) external;

  function add_liquidity(
    uint256[4] calldata amounts,
    uint256 min_mint_amount
  ) external;

  function remove_liquidity_imbalance(
    uint256[2] calldata amounts,
    uint256 max_burn_amount
  ) external;

  function remove_liquidity_imbalance(
    uint256[3] calldata amounts,
    uint256 max_burn_amount
  ) external;

  function remove_liquidity_imbalance(
    uint256[4] calldata amounts,
    uint256 max_burn_amount
  ) external;

  // function remove_liquidity(
  //   uint256 _amount,
  //   uint256[4] calldata amounts
  // ) external;

  // function exchange(
  //   int128 from, int128 to, uint256 _from_amount, uint256 _min_to_amount
  // ) external;
}