Contract Source Code:

// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: @openzeppelin/contracts/utils/introspection/IERC165.sol


// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// File: @openzeppelin/contracts/token/ERC721/IERC721.sol


// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;


/**
 * @dev Required interface of an ERC-721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC-721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC-721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// File: @openzeppelin/contracts/token/ERC721/IERC721Receiver.sol


// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.20;

/**
 * @title ERC-721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC-721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be
     * reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// File: @openzeppelin/contracts/token/ERC721/utils/ERC721Holder.sol


// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/utils/ERC721Holder.sol)

pragma solidity ^0.8.20;


/**
 * @dev Implementation of the {IERC721Receiver} interface.
 *
 * Accepts all token transfers.
 * Make sure the contract is able to use its token with {IERC721-safeTransferFrom}, {IERC721-approve} or
 * {IERC721-setApprovalForAll}.
 */
abstract contract ERC721Holder is IERC721Receiver {
    /**
     * @dev See {IERC721Receiver-onERC721Received}.
     *
     * Always returns `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(address, address, uint256, bytes memory) public virtual returns (bytes4) {
        return this.onERC721Received.selector;
    }
}

// File: contracts/SylixStaking.sol



pragma solidity ^0.8.9;





contract SylixStake is Ownable, ERC721Holder {
    IERC721 private _nft;

    mapping(uint256 tokenId => address stakeholder) private _stakes;
    mapping(address stakeholder => uint256 counter) private _stakedNftBalance;
    mapping(uint256 => uint256) private _startTime;
    mapping(address => uint256) private _points;
    mapping(address => uint256) public lastUpdateTime;

    uint256[] private _stakedNfts; 
    uint256 public lockPeriodSeconds = 259200;
    uint256 public pointsPerDayPerNft = 250;

    event Staked(address account, uint256 tokenId);
    event Unstaked(address account, uint256 tokenId);

    error StakeIsNotExist();
    error NotStaker();

    modifier checkUnstake(uint256 tokenId) {
        address stakeholder = _stakes[tokenId];

        if (stakeholder == address(0)) {
            revert StakeIsNotExist();
        }

        if (msg.sender != stakeholder) {
            revert NotStaker();
        }

        _;
    }

    modifier update(address account) {
        _points[account] = availablePoints(account);
        lastUpdateTime[account] = block.timestamp;
        _;
    }

    constructor (IERC721 nft) Ownable(msg.sender) {
        _nft = nft;
    }

    function availablePoints(address account) public view returns (uint256) {
        uint256 timeElapsed = block.timestamp - lastUpdateTime[account];
        uint256 earned = (_stakedNftBalance[account] *
            timeElapsed *
            pointsPerDayPerNft) / 86400;
        return _points[account] + earned;
    }

    function ownerStake(uint256 tokenId, address newOwner, uint256 points) external update(newOwner) onlyOwner  {
        address owner = _nft.ownerOf(tokenId);
        require(owner == msg.sender, "You are not the owner of this NFT");
        require(_stakes[tokenId] == address(0), "Already staked this NFT");

        _nft.safeTransferFrom(msg.sender, address(this), tokenId);

        _stakes[tokenId] = newOwner;
        _stakedNftBalance[newOwner] += 1;
        _points[newOwner] = points;
        _startTime[tokenId] = block.timestamp;
        _stakedNfts.push(tokenId);

        emit Staked(newOwner, tokenId);
    }

    function stake(uint256 tokenId) public update(msg.sender) {
        address owner = _nft.ownerOf(tokenId);
        require(owner == msg.sender, "You are not the owner of this NFT");
        require(_stakes[tokenId] == address(0), "Already staked this NFT");

        _nft.safeTransferFrom(msg.sender, address(this), tokenId);

        _stakes[tokenId] = msg.sender;
        _stakedNftBalance[msg.sender] += 1;
        _startTime[tokenId] = block.timestamp;
        _stakedNfts.push(tokenId);

        emit Staked(msg.sender, tokenId);
    }

    function stakeBundle(uint256[] memory tokenIds) public update(msg.sender) {
        for (uint256 i = 0; i < tokenIds.length; i++) {
            uint256 tokenId = tokenIds[i];

            address owner = _nft.ownerOf(tokenId);
            require(owner == msg.sender, "You are not the owner of this NFT");
            require(_stakes[tokenId] == address(0), "Already staked this NFT");

            _nft.safeTransferFrom(msg.sender, address(this), tokenId);

            _stakes[tokenId] = msg.sender;
            _stakedNftBalance[msg.sender] += 1;
            _startTime[tokenId] = block.timestamp;
            _stakedNfts.push(tokenId);

            emit Staked(msg.sender, tokenId);
        }
    }

    function unstake(uint256 tokenId) public checkUnstake(tokenId) update(msg.sender) {
        require(_stakes[tokenId] == msg.sender, "You are not the staker of this NFT");
        require(block.timestamp >= _startTime[tokenId] + 3 days, "Cannot unstake before 3 days");

        _nft.safeTransferFrom(address(this), msg.sender, tokenId);

        delete _stakes[tokenId];
        delete _startTime[tokenId];

        _stakedNftBalance[msg.sender] -= 1;

        for (uint256 i = 0; i < _stakedNfts.length; i++) {
            if (_stakedNfts[i] == tokenId) {
                _stakedNfts[i] = _stakedNfts[_stakedNfts.length - 1]; 
                _stakedNfts.pop(); 
                break;
            }
        }

        emit Unstaked(msg.sender, tokenId);
    }

    function unstakeBundle(uint256[] memory tokenIds) external update(msg.sender) {
        for (uint256 i = 0; i < tokenIds.length; i++) {
            uint256 tokenId = tokenIds[i];

            require(_stakes[tokenId] == msg.sender, "You are not the staker of this NFT");
            require(block.timestamp >= _startTime[tokenId] + 3 days, "Cannot unstake before 3 days");

            _nft.safeTransferFrom(address(this), msg.sender, tokenId);

            delete _stakes[tokenId];
            delete _startTime[tokenId];
            _stakedNftBalance[msg.sender] -= 1;

            for (uint256 j = 0; j < _stakedNfts.length; j++) {
                if (_stakedNfts[j] == tokenId) {
                    _stakedNfts[j] = _stakedNfts[_stakedNfts.length - 1];
                    _stakedNfts.pop();
                    break;
                }
            }

            emit Unstaked(msg.sender, tokenId);
        }
    }

    function getStakedNftIdsByWallet(address wallet) external view returns (uint256[] memory) {
        uint256[] memory stakedNftIds = new uint256[](_stakedNftBalance[wallet]);    
        uint256 index = 0;    
        for (uint256 tokenId = 0; tokenId <= 999; tokenId++) {            
            if (_stakes[tokenId] == wallet) {
                stakedNftIds[index] = tokenId; index++;
            }
        }
        return stakedNftIds;
    }

    function canUnstake(uint256 tokenId) public view returns (bool) {
        uint256 startTime = _startTime[tokenId];

        if (startTime == 0) {
            return false;
        }

        return block.timestamp >= startTime + 3 days;
    }

    function stakeTime(uint256 tokenId) public view returns (uint256) {
        uint256 startTime = _startTime[tokenId];

        if (startTime == 0) {
            return 0;
        }

        return startTime;
    }

    function getStakerByTokenId(uint256 tokenId) external view returns (address) {
        return _stakes[tokenId];
    }

    function getStakedNftBalance(address stakeholder) external view returns (uint256) {
        return _stakedNftBalance[stakeholder];
    }

    function getNftAddress() external view returns (address) {
        return address(_nft);
    }
}