Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165Upgradeable.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721Upgradeable is IERC165Upgradeable {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165Upgradeable {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "@openzeppelin/contracts-upgradeable/token/ERC721/IERC721Upgradeable.sol";

interface IWagdie is IERC721Upgradeable {

}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;

import "../external/IWagdie.sol";
import "@openzeppelin/contracts/access/Ownable.sol";


interface IConcord {
    function burn(address _from, uint256 _token, uint256 _quantity) external;
    function balanceOf(address account, uint256 id) external view returns (uint256);
}

interface IWagdieWorld {
    struct WagdieInfo {
        uint64 locationIdCur;
        address owner;
        uint32 emptySpace;
    }

    function wagdieIdToInfo(uint16) external view returns (WagdieInfo memory);
}


contract SearWagdie is Ownable {
    bool public isSearingEnabled;
    address public wagdieAddress;
    address public concordAddress;
    address public wagdieWorldAddress;
    
    mapping(uint16 => uint16) public wagdieSeared;
    mapping(uint16 => bool) public wagdieBlocked;
    mapping(uint16 => bool) public concordBlocked;
    
    event ConcordSeared(uint16 wagdieId, uint16 tokenId, address owner);
    event SearingEnabledChanged(bool isSearingEnabled);

    constructor(address _wagdieAddress, address _concordAddress, address _wagdieWorldAddress) {
        wagdieAddress = _wagdieAddress;
        concordAddress = _concordAddress;
        wagdieWorldAddress = _wagdieWorldAddress;
    }

    function searConcords(
        SearParams[] calldata _searParams)
    external
    {
        require(isSearingEnabled, "Searing is not enabled");
        require(_searParams.length > 0, "No parameters given");

        for(uint256 i = 0; i < _searParams.length; i++) {
            _searConcord(_searParams[i].wagdieId, _searParams[i].tokenId);
        }
    }

    // Sear WAGDIE and Burn Concord
    function _searConcord(
        uint16 _wagdieId,
        uint16 _tokenId)
    private
    {
        require(wagdieSeared[_wagdieId] == 0, "Character Already Seared");
        require(IConcord(concordAddress).balanceOf(msg.sender, _tokenId) > 0, "You Lack Available Concords");
        require(!wagdieBlocked[_wagdieId], "Unable to sear this WAGDIE");
        require(!concordBlocked[_tokenId], "Unable to sear this Concord");
        // Handle staked ownership
        if (msg.sender != IWagdie(wagdieAddress).ownerOf(_wagdieId)) {
            require(msg.sender == IWagdieWorld(wagdieWorldAddress).wagdieIdToInfo(_wagdieId).owner, "Not Character Owner");
        }        
        // Record Token Searing
        wagdieSeared[_wagdieId] = _tokenId;

        // Burn Concord
        IConcord(concordAddress).burn(msg.sender, _tokenId, 1);

        emit ConcordSeared(_wagdieId, _tokenId, msg.sender);
    }

    function updateIsSearingEnabled(bool _isSearingEnabled) external onlyOwner {
        isSearingEnabled = _isSearingEnabled;
        emit SearingEnabledChanged(isSearingEnabled);
    }

    function updateWagdieWorldAddress(address _wagdieWorldAddress) external onlyOwner {
        wagdieWorldAddress = _wagdieWorldAddress;
    }

    function setBlockedWAGDIE(BlockParams[] calldata _blockParams) external onlyOwner {
        for(uint256 i = 0; i < _blockParams.length; i++) {
            wagdieBlocked[_blockParams[i].tokenId] = _blockParams[i].isBlocked;
        }
    }

    function setBlockedConcords(BlockParams[] calldata _blockParams) external onlyOwner {
        require(_blockParams.length > 0, "No parameters given");
        for(uint256 i = 0; i < _blockParams.length; i++) {
            concordBlocked[_blockParams[i].tokenId] = _blockParams[i].isBlocked;
        }
    }
}

struct SearParams {
    // Slot1 (32/256 used)
    uint16 wagdieId;
    uint16 tokenId;
}

struct BlockParams {
    // Slot1 (24/256 used)
    uint16 tokenId;
    bool isBlocked;
}