Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/Address.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!Address.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastValue;
                // Update the index for the moved value
                set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

import "@openzeppelin/contracts/proxy/utils/Initializable.sol";

/**
 * @title DexFiInitializable
 * @dev Abstract contract for initializing contracts with OpenZeppelin's Initializable logic.
 */
abstract contract DexFiInitializable is Initializable {
    // Custom error for indicating that the contract is not initialized.
    error ContractNotInitialized();

    /**
     * @dev Modifier to check if the contract is initialized.
     * Throws a `ContractNotInitialized` error if not initialized.
     */
    modifier onlyInitialized() {
        if (_getInitializedVersion() == 0) revert ContractNotInitialized();
        _;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

import "@openzeppelin/contracts/utils/Address.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
import "./abstracts/utils/DexFiInitializable.sol";
import "./interfaces/IWrapped.sol";
import "./interfaces/IDexFiVault.sol";
import "./interfaces/IDexFiVaultFactory.sol";
import "./interfaces/IDexFiZapperToken.sol";

/**
 * @title DexFiVaultZapper
 * @dev Contract for interacting with DexFiVaults using a whitelist of supported tokens.
 */
contract DexFiVaultZapper is Ownable, ReentrancyGuard, DexFiInitializable {
    using EnumerableSet for EnumerableSet.AddressSet;
    using SafeERC20 for IERC20;

    struct DepositSource {
        address token;
        uint256 amount;
    }

    address public native;
    mapping(address => IDexFiZapperToken) public tokenLogic;

    EnumerableSet.AddressSet private _tokensWhitelist;

    /**
     * @dev Gets the whitelisted token at the specified index.
     * @param index The index of the whitelisted token.
     * @return The address of the whitelisted token.
     */
    function tokensWhitelist(uint256 index) external view returns (address) {
        return _tokensWhitelist.at(index);
    }

    /**
     * @dev Gets the count of whitelisted tokens.
     * @return The count of whitelisted tokens.
     */
    function tokensWhitelistCount() external view returns (uint256) {
        return _tokensWhitelist.length();
    }

    /**
     * @dev Checks if a token is whitelisted.
     * @param token The address of the token to check.
     * @return True if the token is whitelisted, false otherwise.
     */
    function tokensWhitelistContains(address token) external view returns (bool) {
        return _tokensWhitelist.contains(token);
    }

    event TokensWhitelistUpdated(IDexFiZapperToken[] tokens);
    event TokensWhitelistRemoved(address[] tokens);

    error SystemWithdrawRecipientZero();
    error SysthemWithdrawAmountOverflow(uint256 amount, uint256 max);
    error UpdateTokensWhitelistTokenLogicNativeDiffers(address logicNative, address targetNative);
    error DepositSourceTokenUnsupported(address token);
    error DepositTotalNativeAmountZero();
    error WithdrawAmountZero();
    error WithdrawTokenOutUnsupported(address token);
    error WithdrawAmountOutUnderflow(uint256 amountOut, uint256 min);

    receive() external payable {}

    /**
     * @dev Initialize the contract with the address of the DexFiVaultFactory.
     * @param factory The address of the DexFiVaultFactory
     * @return A boolean indicating whether the initialization was successful
     */
    function initialize(IDexFiVaultFactory factory) external initializer returns (bool) {
        native = factory.native();
        return true;
    }

    /**
     * @dev Update the whitelist of tokens with the specified token logic contracts.
     * @param tokens An array of token logic contracts to be added to the whitelist
     * @return A boolean indicating whether the update was successful
     */
    function updateTokensWhitelist(
        IDexFiZapperToken[] memory tokens
    ) external onlyInitialized onlyOwner returns (bool) {
        for (uint256 i = 0; i < tokens.length; i++) {
            IDexFiZapperToken tokenLogic_ = tokens[i];
            if (tokenLogic_.native() != native)
                revert UpdateTokensWhitelistTokenLogicNativeDiffers(tokenLogic_.native(), native);
            address underlying = tokenLogic_.underlying();
            _tokensWhitelist.add(underlying);
            tokenLogic[underlying] = tokenLogic_;
        }
        emit TokensWhitelistUpdated(tokens);
        return true;
    }

    /**
     * @dev Remove tokens from the whitelist.
     * @param underlyings An array of token addresses to be removed from the whitelist
     * @return A boolean indicating whether the removal was successful
     */
    function removeTokensWhitelist(address[] memory underlyings) external onlyInitialized onlyOwner returns (bool) {
        for (uint256 i = 0; i < underlyings.length; i++) {
            address underlying = underlyings[i];
            _tokensWhitelist.remove(underlying);
            delete tokenLogic[underlying];
        }
        emit TokensWhitelistRemoved(underlyings);
        return true;
    }

    /**
     * @dev Deposits assets into a DexFiVault.
     * @param vault The target DexFiVault contract.
     * @param sources Array of DepositSource representing deposit sources.
     * @param minAmountOut Minimum amount of vault tokens to receive in return.
     * @return amountOut The actual amount of vault tokens received.
     */
    function deposit(
        IDexFiVault vault,
        DepositSource[] memory sources,
        uint256 minAmountOut
    ) external payable onlyInitialized nonReentrant returns (uint256 amountOut) {
        uint256 nativeAmount = 0;
        if (msg.value > 0) {
            IWrapped(native).deposit{value: msg.value}();
            nativeAmount += msg.value;
        }
        for (uint256 i = 0; i < sources.length; i++) {
            DepositSource memory source_ = sources[i];
            if (source_.amount > 0) {
                IERC20 sourceToken = IERC20(source_.token);
                sourceToken.safeTransferFrom(msg.sender, address(this), source_.amount);
                if (source_.token == native) nativeAmount += source_.amount;
                else {
                    if (!_tokensWhitelist.contains(source_.token)) revert DepositSourceTokenUnsupported(source_.token);
                    IDexFiZapperToken sourceLogic = tokenLogic[source_.token];
                    sourceToken.forceApprove(address(sourceLogic), source_.amount);
                    nativeAmount += sourceLogic.swapUnderlyingToNative(source_.amount, address(this));
                }
            }
        }
        if (nativeAmount == 0) revert DepositTotalNativeAmountZero();
        IERC20(native).forceApprove(address(vault), nativeAmount);
        amountOut = vault.deposit(nativeAmount, msg.sender, minAmountOut);
    }

    /**
     * @dev Withdraws assets from a DexFiVault.
     * @param vault The target DexFiVault contract.
     * @param amountIn Amount of vault tokens to withdraw.
     * @param tokenOut Address of the token to receive in return.
     * @param minAmountOut Minimum amount of tokenOut to receive in return.
     * @return amountOut The actual amount of tokenOut received.
     */
    function withdraw(
        IDexFiVault vault,
        uint256 amountIn,
        address tokenOut,
        uint256 minAmountOut
    ) external onlyInitialized nonReentrant returns (uint256 amountOut) {
        if (amountIn == 0) revert WithdrawAmountZero();
        amountOut = vault.withdraw(amountIn, msg.sender, 0);
        if (amountOut > 0) {
            if (tokenOut == native) IERC20(native).safeTransfer(msg.sender, amountOut);
            else if (tokenOut == address(0)) {
                IWrapped(native).withdraw(amountOut);
                Address.sendValue(payable(msg.sender), amountOut);
            } else {
                if (!_tokensWhitelist.contains(tokenOut)) revert WithdrawTokenOutUnsupported(tokenOut);
                IDexFiZapperToken tokenOutLogic = tokenLogic[tokenOut];
                IERC20(native).forceApprove(address(tokenOutLogic), amountOut);
                amountOut = tokenOutLogic.swapNativeToUnderlying(amountOut, msg.sender);
            }
        }
        if (amountOut < minAmountOut) revert WithdrawAmountOutUnderflow(amountOut, minAmountOut);
    }

    /**
     * @dev Allows the owner to withdraw assets from the contract.
     * @param token_ Address of the token to withdraw.
     * @param amount Amount of tokens to withdraw.
     * @param recipient Address to receive the withdrawn tokens.
     * @return True on successful withdrawal.
     */
    function systemWithdraw(address token_, uint256 amount, address recipient) external onlyOwner returns (bool) {
        if (recipient == address(0)) revert SystemWithdrawRecipientZero();
        bool isERC20 = token_ != address(0);
        uint256 maxAmount = isERC20 ? IERC20(token_).balanceOf(address(this)) : address(this).balance;
        if (amount > maxAmount) revert SysthemWithdrawAmountOverflow(amount, maxAmount);
        if (isERC20) IERC20(token_).safeTransfer(recipient, amount);
        else Address.sendValue(payable(recipient), amount);
        return true;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

interface IDexFiFarm {
    enum TimeUnit {
        BLOCK,
        SECOND
    }

    function MIN_AMOUNT_OUT() external pure returns (uint256);

    function vault() external view returns (address);

    function native() external view returns (address);

    function stakingToken() external view returns (address);

    function rewardTokens(uint256 index) external view returns (address);

    function rewardTokensCount() external view returns (uint256);

    function farm() external view returns (address);

    function liquidity(address user) external view returns (uint256);

    function stakingTokenType() external view returns (string memory);

    function rewardTokenType(address token) external view returns (string memory);

    function dexVersion() external view returns (uint256);

    function stakingTokenLiquidity(uint256 amount) external returns (uint256);

    function stakingTokenApproveData(address to, uint256 amount) external view returns (bytes memory data);

    function stakingTokenTransferFromData(
        address from,
        address to,
        uint256 amount
    ) external view returns (bytes memory data);

    function timeUnit() external pure returns (TimeUnit);

    function sharePerTimeUnit(address rewardToken) external view returns (uint256);

    function pendingRewards(address token, address user) external view returns (uint256);

    function decodeAndValidateReinitialize(bytes memory params) external view returns (bool);

    function initializationVersion() external view returns (uint8);

    error CallerIsNotVault(address caller, address vault);

    function getAmountOutStakingTokenToNative(uint256 amountIn) external returns (uint256 nativeAmount);

    function getAmountOutRewardTokenToNative(address token, uint256 amountIn) external returns (uint256 nativeAmount);

    function initialize(bytes memory params) external returns (bool);

    function reinitialize(bytes memory params) external returns (bool);

    function deposit(uint256 nativeAmount) external returns (uint256 stakingAmount);

    function depositConvertless(
        uint256 stakingAmount,
        uint256 depositLiquidityAmount,
        uint256 feeLiquidityAmount,
        address feeRecipient,
        address residualsRecipient
    ) external;

    function harvest() external returns (uint256 amount);

    function withdraw(uint256 stakingAmount) external returns (uint256 nativeAmount);

    function withdrawConvertless(uint256 stakingAmount, address recipient) external;

    function emergencyWithdraw(uint256 stakingAmount, address recipient) external;
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

interface IDexFiProfit {
    function MIN_AMOUNT_OUT() external pure returns (uint256);

    function initializationVersion() external view returns (uint8);

    function factory() external view returns (address);

    function native() external view returns (address);

    function underlying() external view returns (address);

    function underlyingType() external view returns (string memory);

    function decodeAndValidateReinitialize(bytes memory params) external view returns (bool);

    error ReinitalizeCallerNotFactory(address caller, address factory);

    function getAmountOutUnderlyingToNative(uint256 underlyingAmount) external returns (uint256 nativeAmount);

    function initialize(bytes memory params) external returns (bool);

    function reinitialize(bytes memory params) external returns (bool);

    function swapNativeToProfit(uint256 nativeAmount) external returns (uint256 profitAmount, uint256 usedNativeAmount);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

import "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import "./IDexFiVaultFactory.sol";
import "./IDexFiVaultProfitStorage.sol";
import "./IDexFiFarm.sol";

interface IDexFiVault {
    struct Farm {
        address beacon;
        uint256 percent;
        bytes data;
    }

    struct PublishData {
        bool published;
        address publisher;
    }

    function divider() external view returns (uint256);

    function lastHarvestTimestamp() external view returns (uint256);

    function factory() external view returns (IDexFiVaultFactory);

    function harvesterDebt() external view returns (uint256);

    function profit() external view returns (uint256);

    function profitStorage() external view returns (address);

    function native() external view returns (IERC20Upgradeable);

    function farmConnector(address) external view returns (IDexFiFarm);

    function publishData() external view returns (PublishData memory);

    function farms(uint256 index) external view returns (Farm memory);

    function farmsCount() external view returns (uint256);

    function convertlessDepositRatio() external view returns (uint256[] memory output);

    event Published(address publisher);
    event ProfitUpdated(uint256 profit);
    event HarvesterDebtIncreased(uint256 amount, uint256 remainingDebtAmount);
    event Deposited(
        address indexed user,
        address indexed to,
        uint256 nativeAmount,
        uint256 syntheticAmount,
        uint256 feeAmount
    );
    event ConvertlessDeposited(
        address indexed user,
        uint256 syntheticAmount,
        uint256[] stakingAmounts,
        uint256[] depositLiquidityAmounts,
        uint256[] feeLiquidityAmounts
    );
    event Harvested(
        address indexed user,
        uint256 reinvestAmount,
        uint256 feeAmount,
        uint256 profitAmount,
        uint256 paidDebtAmount,
        uint256 remainingDebtAmount
    );
    event Withdrawn(
        address indexed user,
        address indexed from,
        uint256 syntheticAmount,
        uint256 nativeAmount,
        uint256 feeAmount
    );
    event EmergencyWithdrawn(address indexed user, uint256 syntheticAmount, uint256[] outputAmounts);
    event ConvertlessWithdrawn(
        address indexed user,
        uint256 syntheticAmount,
        uint256[] outputAmounts,
        uint256[] feeAmounts,
        uint256 outputNativeAmount,
        uint256 feeNativeAmount
    );
    event FarmsUpdated(Farm[] farms);

    error ActualizeFarmStatusReinitializationFailed(address farm, bytes data);
    error IncreaseHarvesterDebtCallerNotHarvester(address caller, address harvester);
    error DepositAmountZero();
    error DepositUsersCountOverflow();
    error DepositLiquidityNotPositive();
    error DepositMintAmountUnderflow(uint256 mintAmount, uint256 minMintAmount);
    error DepositConvertlessSupplyZero();
    error DepositConvertlessAmountsLengthDiffers(uint256 amountsLength, uint256 target);
    error DepositConvertlessMintAmountUnderflow(uint256 mintAmount, uint256 minMintAmount);
    error WithdrawAmountZero();
    error WithdrawNativeAmountUnderflow(uint256 nativeAmount, uint256 minNativeAmount);
    error EmergencyWithdrawUserBalanceZero();
    error WithdrawConvertlessAmountZero();
    error UpdateProfitUnderflow(uint256 profit, uint256 min);
    error UpdateProfitOverflow(uint256 profit, uint256 max);
    error ProtocolPaused();
    error ContractNotInitialized();
    error RestakingAmountUnderflow(uint256 restakingAmount, uint256 minRestakingAmount);
    error UpdateFarmsLengthZero();
    error UpdateFarmsInvalidPercentsSum(uint256 percentSum, uint256 targetSum);

    function increaseHarvesterDebt(uint256 amount) external returns (bool);

    function initialize(
        string memory name_,
        string memory symbol_,
        address owner_,
        uint256 profit_,
        address profitToken_,
        Farm[] memory farms_
    ) external returns (bool);

    function deposit(uint256 amount, address to, uint256 minMintAmount) external returns (uint256 mintAmount);

    function depositConvertless(
        uint256[] memory stakingAmounts,
        uint256 minMintAmount
    ) external returns (uint256 mintAmount);

    function harvest(
        uint256 minRestakingAmount_
    )
        external
        returns (
            uint256 reinvestAmount,
            uint256 harvestFeeAmount,
            uint256 profitAmount,
            uint256 paidDebtAmount,
            uint256 remainingDebtAmount,
            uint256 restakingAmount
        );

    function updateFarms(
        Farm[] memory farms_,
        uint256 minRestakingAmount_
    ) external returns (uint256 restakingAmount, uint256 liquidityInNative);

    function withdraw(uint256 amount, address from, uint256 minNativeAmount) external returns (uint256 nativeAmount);

    function emergencyWithdraw() external returns (uint256[] memory outputAmounts);

    function publish(uint256 minRestakingAmount_) external returns (uint256 restakingAmount);

    function updateProfit(uint256 profit_) external returns (bool);

    function updateProfitToken(address profitToken_) external returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

import "./IDexFiVault.sol";
import "./IDexFiVaultProfitStorage.sol";
import "./IDexFiProfit.sol";
import "./IDexFiFarm.sol";

interface IDexFiVaultFactory {
    struct FeeConfig {
        uint256 depositFee;
        uint256 harvestFee;
        uint256 withdrawFee;
        uint256 migrateFee;
    }

    struct ProfitConfig {
        uint256 minProfit;
        uint256 maxProfit;
        address profitStorageImplementation;
        uint256 vaultOwnerProfit;
    }

    struct VaultConfig {
        address vaultImplementation;
        uint256 maxDepositorsCount;
        uint256 initialPriceNativeAmount;
        uint256 minSyntheticTransferAmount;
        uint256 minNativeReinvestAmount;
    }

    struct IntegrationConfig {
        address operator;
        address keeper;
        address harvester;
        address migrator;
        address treasury;
        address profitClaimer;
        address zapper;
    }

    struct InitializableConfig {
        address source;
        bytes defaultInitializeData;
    }

    struct Beaconed {
        address beacon;
        address source;
        bytes defaultInitializeData;
    }

    function DIVIDER() external view returns (uint256);

    function MAX_DEPOSIT_FEE() external view returns (uint256);

    function MAX_HARVEST_FEE() external view returns (uint256);

    function MAX_WITHDRAW_FEE() external view returns (uint256);

    function MAX_MIGRATE_FEE() external view returns (uint256);

    function MIN_VAULT_MANAGEMENT_AMOUNT() external view returns (uint256);

    function MAX_VAULT_OWNER_PROFIT() external view returns (uint256);

    function MIN_DEPOSITORS_COUNT() external view returns (uint256);

    function MAX_DEPOSITORS_COUNT() external view returns (uint256);

    function native() external view returns (address);

    function defaultFarmsInitializeData(address) external view returns (bytes memory);

    function defaultFarmsInitializeDataTimestamp(address) external view returns (uint256);

    function profitTokenConnector(address) external view returns (IDexFiProfit);

    function farmCalculationConnector(address) external view returns (IDexFiFarm);

    function feeConfig() external view returns (FeeConfig memory);

    function profitConfig() external view returns (ProfitConfig memory);

    function vaultConfig() external view returns (VaultConfig memory);

    function integrationConfig() external view returns (IntegrationConfig memory);

    function farmsWhitelist(uint256 index) external view returns (address);

    function farmsWhitelistCount() external view returns (uint256);

    function farmsWhitelistContains(address farm) external view returns (bool);

    function profitTokensWhitelist(uint256 index) external view returns (address);

    function profitTokensWhitelistCount() external view returns (uint256);

    function profitTokensWhitelistContains(address profitToken) external view returns (bool);

    function vaults(uint256 index) external view returns (address);

    function vaultsCount() external view returns (uint256);

    function vaultsContains(address vault) external view returns (bool);

    function harvesterBlacklist(uint256 index) external view returns (address);

    function harvesterBlacklistCount() external view returns (uint256);

    function harvesterBlacklistContains(address vault) external view returns (bool);

    error NativeZero();
    error CallerNotOwnerOrOperator(address caller, address owner, address operator);

    error CreateVaultProfitTokenUnsupported(address profitToken);
    error CreateVaultInitializationFailed();

    error UpdateFarmsWhitelistBeaconNotWhitelisted(address beacon);
    error UpdateFarmsWhitelistBeaconSourceZero(address beacon);
    error UpdateFarmsWhitelistReinitializationFailed(Beaconed data);

    error UpdateProfitTokensWhitelistBeaconNotWhitelisted(address beacon);
    error UpdateProfitTokensWhitelistBeaconSourceZero(address beacon);
    error UpdateProfitTokensWhitelistReinitializationFailed(Beaconed data);

    error UpdateFeeConfigDepositFeeOverflow(uint256 depositFee, uint256 limit);
    error UpdateFeeConfigHarvestFeeOverflow(uint256 harvestFee, uint256 limit);
    error UpdateFeeConfigWithdrawFeeOverflow(uint256 withdrawFee, uint256 limit);
    error UpdateFeeConfigMigrateFeeOverflow(uint256 migrateFee, uint256 limit);

    error UpdateVaultConfigVaultImplementationZero();
    error UpdateVaultConfigInvalidMaxDepositors(uint256 maxDepositors, uint256 min, uint256 max);
    error UpdateVaultConfigVaultInitialPriceNativeAmountUnderflow(uint256 initialPriceNativeAmount, uint256 min);
    error UpdateVaultConfigMinSyntheticTransferAmountUnderflow(uint256 minSyntheticTransferAmount, uint256 min);
    error UpdateVaultConfigMinReinvestAmountZero();
    error UpdateProfitConfigMaxProfitOverflow(uint256 maxProfit, uint256 max);
    error UpdateProfitConfigMinProfitOverflow(uint256 minProfit, uint256 maxProfit);
    error UpdateProfitConfigProfitStorageImplementationZero();
    error UpdateProfitConfigVaultOwnerProfitOverflow(uint256 vaultOwnerProfit, uint256 max);

    error UpdateIntegrationConfigOperatorZero();
    error UpdateIntegrationConfigKeeperZero();
    error UpdateIntegrationConfigHarvesterZero();
    error UpdateIntegrationConfigMigratorZero();
    error UpdateIntegrationConfigTreasuryZero();
    error UpdateIntegrationConfigProfitClaimerZero();
    error UpdateIntegrationConfigZapperZero();

    error ToggleVaultAutoHarvestCallerNotVaultOwner(address caller, address vault, address owner);

    error AddProfitTokensWhitelistProfitTokenZero();
    error AddProfitTokensWhitelistInitializationFailed(Beaconed data);

    error AddFarmsWhitelistFarmZero();
    error AddFarmsWhitelistInitializationFailed(Beaconed data);
    error AddFarmsWhitelistBeaconNotWhitelisted(address beacon);

    event VaultCreated(
        address indexed owner,
        address vault,
        uint256 profit,
        address profitToken,
        IDexFiVault.Farm[] farms
    );
    event FeeConfigUpdated(FeeConfig config);
    event VaultConfigUpdated(VaultConfig config);
    event ProfitConfigUpdated(ProfitConfig config);
    event IntegrationConfigUpdated(IntegrationConfig config);
    event VaultAutoHarvestToggled(address vault, bool blacklisted);
    event ProfitTokensWhitelistAdded(Beaconed[] profitTokens);
    event ProfitTokensWhitelistUpdated(Beaconed[] profitTokens);
    event ProfitTokensWhitelistRemoved(address[] profitTokens);
    event FarmsWhitelistAdded(Beaconed[] farms);
    event FarmsWhitelistUpdated(Beaconed[] farms);
    event FarmsWhitelistRemoved(address[] farms);

    function createVault(
        string memory name_,
        string memory symbol_,
        uint256 profit_,
        address profitToken_,
        IDexFiVault.Farm[] memory farms_
    ) external returns (address vault);

    function pause() external returns (bool);

    function unpause() external returns (bool);

    function addFarmsWhitelist(InitializableConfig[] memory farms_) external returns (Beaconed[] memory output);

    function updateFarmsWhitelist(Beaconed[] memory farms_) external returns (bool);

    function removeFarmsWhitelist(address[] memory beacons_) external returns (bool);

    function addProfitTokensWhitelist(
        InitializableConfig[] memory profitTokens_
    ) external returns (Beaconed[] memory output);

    function updateProfitTokensWhitelist(Beaconed[] memory profitTokens_) external returns (bool);

    function removeProfitTokensWhitelist(address[] memory beacons_) external returns (bool);

    function updateFeeConfig(FeeConfig memory config) external returns (bool);

    function updateVaultConfig(VaultConfig memory config) external returns (bool);

    function updateProfitConfig(ProfitConfig memory config) external returns (bool);

    function updateIntegrationConfig(IntegrationConfig memory config) external returns (bool);

    function toggleVaultAutoHarvest(address vault) external returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "./IDexFiVaultFactory.sol";
import "./IDexFiVault.sol";
import "./IDexFiProfit.sol";

interface IDexFiVaultProfitStorage {
    struct UserSyntheticAmount {
        address user;
        uint256 amount;
    }

    struct UserSharesInfo {
        uint256 accShares;
        uint256 lastRewardBlock;
        uint256 lastSyntheticBalance;
    }

    function divider() external view returns (uint256);

    function factory() external view returns (IDexFiVaultFactory);

    function vault() external view returns (address);

    function profitToken() external view returns (address);

    function profitTokenConnector() external view returns (IDexFiProfit);

    function usersSharesInfo(address user) external view returns (UserSharesInfo memory);

    function availableToClaim(address) external view returns (uint256);

    function fund() external view returns (uint256);

    function native() external view returns (IERC20);

    function users(uint256 index) external view returns (address);

    function usersCount() external view returns (uint256);

    function usersContains(address user) external view returns (bool);

    event ProfitFundsAdded(uint256 amount);
    event ProfitTokenUpdated(address profitToken);
    event Claimed(address indexed user, address indexed token, uint256 amount);
    event UserAdded(address indexed user);
    event UserRemoved(address indexed user);

    error CallerNotVault(address caller, address vault);
    error AddProfitFundsAmountZero();
    error UpdateProfitTokenVaultPublished();
    error ClaimAmountOverflow(uint256 amount, uint256 max);
    error UpdateProfitTokenUnsupported(address token);

    function initialize(IDexFiVaultFactory factory_, address profitToken_) external returns (bool);

    function updateUsersSharesBalance(UserSyntheticAmount[] memory usersSyntheticAmount) external returns (bool);

    function allocate() external returns (bool);

    function addProfitFunds(uint256 amount) external returns (bool);

    function claim(uint256 amount, address from) external returns (bool);

    function updateProfitToken(address profitToken_) external returns (bool);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

interface IDexFiZapperToken {
    function MIN_AMOUNT_OUT() external pure returns (uint256);

    function native() external view returns (address);

    function underlying() external view returns (address);

    function getAmountOutUnderlyingToNative(uint256 underlyingAmount) external returns (uint256 nativeAmount);

    function swapUnderlyingToNative(uint256 underlyingAmount, address to) external returns (uint256 nativeAmount);

    function swapNativeToUnderlying(uint256 nativeAmount, address to) external returns (uint256 underlyingAmount);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity 0.8.21;

interface IWrapped {
    function deposit() external payable;

    function withdraw(uint256) external;
}