Contract Source Code:

pragma solidity ^0.4.24;

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 {
    function allowance(address owner, address spender) public view returns (uint256);
    function transferFrom(address from, address to, uint256 value) public returns (bool);
    function approve(address spender, uint256 value) public returns (bool);
    event Approval(address indexed owner, address indexed spender, uint256 value);
    function totalSupply() public view returns (uint256);
    function balanceOf(address who) public view returns (uint256);
    function transfer(address to, uint256 value) public returns (bool);
    event Transfer(address indexed from, address indexed to, uint256 value);
}

pragma solidity ^0.4.24;


import "./Ownable.sol";


/**
 * @title Lockable
 * @dev lock up token transfer during duration. This helps lock up private and pre-sale investor cannot sell token certain period.
 * @author Geunil(Brian) Lee
 */
contract Lockable is Ownable {
  
    /**
    * @dev hold lock up address and duration
    */
    mapping(address => uint256) public lockedUp;
  
    uint public nowTime;
    
    constructor () public {
        nowTime = now;        
    }

    /**
    * @dev lock up by pass when duration is passed or not exist on lockedUp mapping.
    */
    modifier whenNotLockedUp() {
        require(lockedUp[msg.sender] < now || lockedUp[msg.sender] == 0 );
        _;
    }


    /**
    * @dev lock up status
    * @return true - no lock up. false - locked up 
    */
    function nolockedUp(address sender) public view returns (bool){
        if(lockedUp[sender] < now || lockedUp[sender] == 0){
            return true; 
        }
        return false;                
    }
  
    /**
    * @dev add lock up investor to mapping
    * @param _investor lock up address
    * @param _duration lock up period. unit is days
    */
    function addLockUp(address _investor, uint _duration ) onlyOwner public {
        require(_investor != address(0) && _duration > 0);
        lockedUp[_investor] = now + _duration * 1 days; 
    }
    
    /**
    * @dev remove lock up address from mapping
    * @param _investor lock up address to be removed from mapping
    */
    function removeLockUp(address _investor ) onlyOwner public {
        require(_investor != address(0));
        delete lockedUp[_investor]; 
    }
  
  
}

pragma solidity ^0.4.24;


/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 * based on https://https://github.com/OpenZeppelin/zeppelin-solidity. modified to have multiple ownership.
 * @author Geunil(Brian) Lee
 */
contract Ownable {
  
    /**
    * Ownership can be owned by multiple owner. Useful when have multiple contract to communicate  each other
    **/
    mapping (address => bool) public owner;
  
    event OwnershipAdded(address newOwner);
    event OwnershipRemoved(address noOwner);    

    /**
    * @dev The Ownable constructor sets the original `owner` of the contract to the sender
    * account.
    */
    constructor () public {
        owner[msg.sender] = true;        
    }

    /**
    * @dev Throws if called by any account other than the owner.
    */
    modifier onlyOwner() {
        require(owner[msg.sender] == true);
        _;
    }

    /**
    * @dev Add ownership
    * @param _newOwner add address to the ownership
    */
    function addOwnership(address _newOwner) public onlyOwner {
        require(_newOwner != address(0));
        owner[_newOwner] = true;
        emit OwnershipAdded(_newOwner);
    }
  
    /**
    * @dev Remove ownership
    * @param _ownership remove ownership
    */
    function removeOwner(address _ownership) public onlyOwner{
        require(_ownership != address(0));
        // owner cannot remove ownerhip itself
        require(msg.sender != _ownership);
        delete owner[_ownership];
        emit OwnershipRemoved(_ownership);
    }

}

pragma solidity ^0.4.24;


/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 * based on https://https://github.com/OpenZeppelin/zeppelin-solidity.
 */
library SafeMath {

    /**
    * @dev Multiplies two numbers, throws on overflow.
    */
    function mul(uint256 a, uint256 b) internal pure returns (uint256 c) {
        if (a == 0) {
            return 0;
        }
        c = a * b;
        assert(c / a == b);
        return c;
    }

    /**
    * @dev Integer division of two numbers, truncating the quotient.
    */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        // assert(b > 0); // Solidity automatically throws when dividing by 0
        // uint256 c = a / b;
        // assert(a == b * c + a % b); // There is no case in which this doesn't hold
        return a / b;
    }

    /**
    * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
    */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        assert(b <= a);
        return a - b;
    }

    /**
    * @dev Adds two numbers, throws on overflow.
    */
    function add(uint256 a, uint256 b) internal pure returns (uint256 c) {
        c = a + b;
        assert(c >= a);
        return c;
    }
}

pragma solidity ^0.4.24;

import "./Ownable.sol";
import "./ERC20.sol";
import "./SafeMath.sol";
import "./Lockable.sol";


/**
 * @title TEMCO token
 * @dev Based on code by https://https://github.com/OpenZeppelin/zeppelin-solidity
 * @author Geunil(Brian) Lee
 */
contract TemcoToken is ERC20, Ownable, Lockable {
  
    using SafeMath for uint256;
      
    event OwnedValue(address owner, uint256 value);
    event Mint(address to, uint256 amount);
    event MintFinished();
    event Burn(address burner, uint256 value);
    
    mapping(address => uint256) public balances;    
    mapping (address => mapping (address => uint256)) internal allowed;

    uint256 public totalSupply;
    function totalSupply() public view returns (uint256) {
        return totalSupply;
    }
  
    // Public variables of the token
    string public name;
    string public symbol;
    uint8 public decimals = 18;
    
    bool public mintingFinished = false;    
    
    /**
    * Constructor function
    *
    * Initializes contract with initial supply tokens to the creator of the contract
    */
    constructor (
        uint256 initialSupply,
        string tokenName,
        string tokenSymbol
    )public {
        totalSupply = initialSupply * 10 ** uint256(decimals);  // Update total supply with the decimal amount
        emit OwnedValue(msg.sender, 0);
        balances[msg.sender] = totalSupply;                // Give the creator all initial tokens
        name = tokenName;                                   // Set the name for display purposes
        symbol = tokenSymbol;                             // Set the symbol for display purposes
    }
      
    /**
    * @dev transfer token for a specified address
    * @param _to The address to transfer to.
    * @param _value The amount to be transferred.
    */
    function transfer(address _to, uint256 _value) public whenNotLockedUp returns (bool) {        
        emit OwnedValue(msg.sender, _value);
                
        require(_to != address(0));
        require(_to != address(this));
        require(_value <= balances[msg.sender]); 

        // SafeMath.sub will throw if there is not enough balance.
        balances[msg.sender] = balances[msg.sender].sub(_value);
        balances[_to] = balances[_to].add(_value);
        emit Transfer(msg.sender, _to, _value);
        return true;
    }
    
    /**
    * @dev Transfer tokens from one address to another
    * @param _from address The address which you want to send tokens from
    * @param _to address The address which you want to transfer to
    * @param _value uint256 the amount of tokens to be transferred
    */
    function transferFrom(address _from, address _to, uint256 _value) public returns (bool) {
        require(_to != address(0));
        require(_to != address(this));
        require(_value <= balances[_from]);
        require(_value <= allowed[_from][msg.sender]);
        if(nolockedUp(_from) == false){
            return false;
        }
        balances[_from] = balances[_from].sub(_value);
        balances[_to] = balances[_to].add(_value);
        allowed[_from][msg.sender] = allowed[_from][msg.sender].sub(_value);
        emit Transfer(_from, _to, _value);
        return true;
    }

    /**
    * @dev Approve the passed address to spend the specified amount of tokens on behalf of msg.sender.
    *
    * Beware that changing an allowance with this method brings the risk that someone may use both the old
    * and the new allowance by unfortunate transaction ordering. One possible solution to mitigate this
    * race condition is to first reduce the spender's allowance to 0 and set the desired value afterwards:
    * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    * @param _spender The address which will spend the funds.
    * @param _value The amount of tokens to be spent.
    */
    function approve(address _spender, uint256 _value) public whenNotLockedUp returns (bool) {
        allowed[msg.sender][_spender] = _value;
        emit Approval(msg.sender, _spender, _value);
        return true;
    }
  
    /**
    * @dev Gets the balance of the specified address.
    * @param _owner The address to query the balance of.
    * @return An uint256 representing the amount owned by the passed address.
    */
    function balanceOf(address _owner) public view returns (uint256 balance) {
        return balances[_owner];
    }

    /**
    * @dev Function to check the amount of tokens that an owner allowed to a spender.
    * @param _owner address The address which owns the funds.
    * @param _spender address The address which will spend the funds.
    * @return A uint256 specifying the amount of tokens still available for the spender.
    */
    function allowance(address _owner, address _spender) public view returns (uint256) {
        return allowed[_owner][_spender];
    }

    /**
    * @dev Increase the amount of tokens that an owner allowed to a spender.
    *
    * approve should be called when allowed[_spender] == 0. To increment
    * allowed value is better to use this function to avoid 2 calls (and wait until
    * the first transaction is mined)
    * From MonolithDAO Token.sol
    * @param _spender The address which will spend the funds.
    * @param _addedValue The amount of tokens to increase the allowance by.
    */
    function increaseApproval(address _spender, uint _addedValue) whenNotLockedUp public returns (bool) {
        allowed[msg.sender][_spender] = allowed[msg.sender][_spender].add(_addedValue);
        emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
        return true;
    }

    /**
    * @dev Decrease the amount of tokens that an owner allowed to a spender.
    *
    * approve should be called when allowed[_spender] == 0. To decrement
    * allowed value is better to use this function to avoid 2 calls (and wait until
    * the first transaction is mined)
    * From MonolithDAO Token.sol
    * @param _spender The address which will spend the funds.
    * @param _subtractedValue The amount of tokens to decrease the allowance by.
    */
    function decreaseApproval(address _spender, uint _subtractedValue) whenNotLockedUp public returns (bool) {
        uint oldValue = allowed[msg.sender][_spender];
        if (_subtractedValue > oldValue) {
            allowed[msg.sender][_spender] = 0;
        } else {
            allowed[msg.sender][_spender] = oldValue.sub(_subtractedValue);
        }
        emit Approval(msg.sender, _spender, allowed[msg.sender][_spender]);
        return true;
    }
  
    /**
    * @dev Burns a specific amount of tokens.
    * @param _value The amount of token to be burned.
    */
    function burn(uint256 _value) external onlyOwner {
        require(_value <= balances[msg.sender]);
        // no need to require value <= totalSupply, since that would imply the
        // sender's balance is greater than the totalSupply, which *should* be an assertion failure

        address burner = msg.sender;
        balances[burner] = balances[burner].sub(_value);
        totalSupply = totalSupply.sub(_value);
        emit Burn(burner, _value);
        emit Transfer(burner, address(0), _value);
    }
  
    modifier canMint() {
        require(!mintingFinished);
        _;
    }

    /**
    * @dev Function to mint tokens
    * @param _to The address that will receive the minted tokens.
    * @param _amount The amount of tokens to mint.
    * @return A boolean that indicates if the operation was successful.
    */
    function mint(address _to, uint256 _amount) onlyOwner canMint external returns (bool) {
        require(_to != address(0) && _amount > 0);
        totalSupply = totalSupply.add(_amount);
        balances[_to] = balances[_to].add(_amount);
        emit Mint(_to, _amount);
        emit Transfer(address(0), _to, _amount);
        return true;
    }

    /**
    * @dev Function to mint tokens
    * @param _to The address that will receive the minted tokens.
    * @param _amount The amount of tokens to mint.
    * @return A boolean that indicates if the operation was successful.
    */
    function mintTo(address _from, address _to, uint256 _amount) onlyOwner canMint external returns (bool) {
        require(_from != address(0)  && _to != address(0) && _amount > 0);        
        balances[_from] = balances[_from].sub(_amount);
        balances[_to] = balances[_to].add(_amount);        
        emit Mint(_to, _amount);
        emit Transfer(address(0), _to, _amount);
        return true;
    }

    /**
    * @dev Function to stop minting new tokens.
    * @return True if the operation was successful.
    */
    function finishMinting() onlyOwner canMint external returns (bool) {
        mintingFinished = true;
        emit MintFinished();
        return true;
    }
  
}